Flash Mobile Drawing: Graphics Source Code

package
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Graphics;
	import flash.display.MovieClip;
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.geom.Matrix;
	import flash.geom.Point;
	import flash.utils.Dictionary;
 
	[SWF(backgroundColor='#000000', frameRate='60')]
 
	public class POC_BlittingGraphics extends Sprite
	{
		//--------------------------------------------------------------------------
		//
		//  Constants
		//
		//--------------------------------------------------------------------------
 
		private const DRAW_MODE_GRAPHICS:String = "graphics";
		private const DRAW_MODE_BITMAP:String = "bitmap";
 
		//--------------------------------------------------------------------------
		//
		//  Constructor
		//
		//--------------------------------------------------------------------------
 
		public function POC_BlittingGraphics()
		{
			super();
 
			//iconBitmap = new Bitmap(new BitmapData(64, 64, false, 0xFF0000));
			iconBitmap = new ImageClass() as Bitmap;
 
			var blitmap:BlitData;
 
			if(drawMode == DRAW_MODE_GRAPHICS)
			{
				canvasShape = new Shape();
				this.addChild(canvasShape);
			}
			else if(drawMode == DRAW_MODE_BITMAP)
			{
				canvasBitmap = new Bitmap();
				this.addChild(canvasBitmap);
			}
 
			this.addChild(new FPSMemCounter(0xFFFFFF));
 
			for(var i:int = 0 ; i < 15 ; i++)
			{
				blitmap = new BlitData();
				blitmap.x = 360 * Math.random();
				blitmap.y = 660 * Math.random();
				blitmap.velocityX = (Math.random() * 4) - 2;
				blitmap.velocityY = (Math.random() * 4) - 2;
				blitmap.width = iconBitmap.width;
				blitmap.height = iconBitmap.height;
				blitDataDictionary["data_" + i] = blitmap;
			}
 
			this.stage.align = StageAlign.TOP_LEFT;
			this.stage.scaleMode = StageScaleMode.NO_SCALE;
			//this.stage.quality = StageQuality.LOW;
 
			this.addEventListener(Event.ENTER_FRAME, onEnterFrame);
		}
 
		//--------------------------------------------------------------------------
		//
		//  Variables
		//
		//--------------------------------------------------------------------------
 
		[Embed(source="bad-egg-icon.png")]
		private var ImageClass:Class;
 
		private var iconBitmap:Bitmap;
		private var canvasShape:Shape;
		private var canvasBitmap:Bitmap;
		private var blitDataDictionary:Dictionary = new Dictionary();
		private var drawMode:String = DRAW_MODE_BITMAP;
 
		//--------------------------------------------------------------------------
		//
		//  Private methods
		//
		//--------------------------------------------------------------------------
 
		private function moveActor(blitData:BlitData):void
		{
			blitData.x += blitData.velocityX;
			blitData.y += blitData.velocityY;
 
			if(blitData.x >= stage.stageWidth - blitData.width || blitData.x <= 0)
			{
				blitData.velocityX *= -1;
			}
 
			if(blitData.y >= stage.stageHeight - blitData.height || blitData.y <= 0)
			{
				blitData.velocityY *= -1;
			}
		}
 
		private function drawShape(canvasShapeGraphics:Graphics, blitData:BlitData, bd:BitmapData):void
		{
			canvasShapeGraphics.beginBitmapFill(bd, new Matrix(1, 0, 0, 1, blitData.x, blitData.y), false, false);
			canvasShapeGraphics.drawRect(blitData.x, blitData.y, bd.width, bd.height);
		}
 
		private function drawBitmap(canvasBitmapData:BitmapData, blitData:BlitData, bd:BitmapData):void
		{
			canvasBitmapData.copyPixels(bd, bd.rect, new Point(blitData.x, blitData.y));
		}
 
		//--------------------------------------------------------------------------
		//
		//  Event handlers
		//
		//--------------------------------------------------------------------------
 
		private function onEnterFrame(event:Event):void
		{
			var blitData:BlitData;
 
			if(drawMode == DRAW_MODE_GRAPHICS)
			{
				canvasShape.graphics.clear();
 
				for each(blitData in blitDataDictionary)
				{
					moveActor(blitData);
					drawShape(canvasShape.graphics, blitData, iconBitmap.bitmapData);
				}
			}
			else if(drawMode == DRAW_MODE_BITMAP)
			{
				var bd:BitmapData = new BitmapData(this.stage.stageWidth, this.stage.stageHeight, false, 0x000000);
 
				for each(blitData in blitDataDictionary)
				{
					moveActor(blitData);
					drawBitmap(bd, blitData, iconBitmap.bitmapData);
				}
 
				canvasBitmap.bitmapData = bd;
			}
		}
	}
}
 
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;
 
internal class BlitData
{
	//--------------------------------------------------------------------------
	//
	//  Constructor
	//
	//--------------------------------------------------------------------------
 
	public function BlitData()
	{
		super();
	}
 
	//--------------------------------------------------------------------------
	//
	//  Properties
	//
	//--------------------------------------------------------------------------
 
	public var x:Number;
	public var y:Number;
	public var velocityX:Number;
	public var velocityY:Number;
	public var width:Number;
	public var height:Number;
}
 
import flash.display.Stage;
import flash.system.System;
import flash.events. *;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.utils.getTimer;
 
internal class FPSMemCounter extends TextField
{
	private var fontSize : Number; //the font size for the field
	private var lastUpdate : Number; // the results of getTimer() from the last update
	private var frameCount : Number; //stores the count of frames passed this second
	private var currentTime : Number;
	private static const UPDATE_INTERVAL : Number = 1000; //the interval at which the frame count will be be posted
 
	public function FPSMemCounter (textColor : Number = 0xFFFFFF, fontSize : Number = 25) : void
	{
		this.textColor = textColor;
		this.fontSize = 12;
 
		//set the field to autosize from the left
		autoSize = TextFieldAutoSize.LEFT;
 
		//make the text unselecteable and disable mouse events
		selectable = false;
		mouseEnabled = false;
 
		addEventListener (Event.ADDED_TO_STAGE, setFPSUpdate);
		addEventListener (Event.REMOVED_FROM_STAGE, clearFPSUpdate);
	}
 
	//called when the instance is added to a Display Object
	private function setFPSUpdate (event : Event) : void
	{
		addEventListener (Event.ENTER_FRAME, updateFPS);
		frameCount = 0;
		updateText (frameCount);
		lastUpdate = getTimer ();
	}
	//called when the instance is removed from a Display Object
	private function clearFPSUpdate (event : Event) : void
	{
		removeEventListener (Event.ENTER_FRAME, updateFPS);
	}
 
	//update the frame counter
	private function updateFPS (event : Event) : void
	{
		//get the current time and increment the frame counter
		currentTime = getTimer ();
		frameCount ++;
 
		//post the frame count if more then a second has passed
		if (currentTime >= lastUpdate + UPDATE_INTERVAL)
		{
			lastUpdate = currentTime;
			updateText (frameCount);
			frameCount = 0;
		}
	}
 
	//update the display text
	private function updateText (frameNum : Number) : void
	{
		var mem:String = Number( System.totalMemory / 1024 / 1024 ).toFixed( 2 ) + 'Mb';
		htmlText = "<font size='" + fontSize + "'><b>FPS : </b>" + frameNum + " fps</b><b> Memory : </b>"+ mem +"</font>";
	}
 
}